# C:\Users\stefano.maggi.CONBIPELSPA\Desktop\prom38.png

**Date**: 12/05/2012

**Procedure:** SQL Server - Disable Clustered Index and Data Insert

**Source:** [**LINK**](http://blog.sqlauthority.com/2010/04/29/sql-server-disable-clustered-index-and-data-insert/)

**Permalink:** [**LINK**](http://heelpbook.altervista.org/2012/sql-server-disable-clustered-index-and-data-insert/)

**Created by:** HeelpBook Staff

**Document Version:** 1.0

# **SQL Server – Disable Clustered Index and Data Insert**

**Clustered indexes** are in fact original tables (or heap) which are physically ordered (any more things – not scope of this article) according to one or more keys (**columns**). When a **clustered index** is *disabled*, its data rows cannot be accessed. *This means that there will be no insertion process possible*. On the other hand, when **non-clustered indexes** are disabled, all the data related to it are physically deleted, but the definition of the index is kept in the system.

Due to the same reason, even reorganization of the index is not possible until the **clustered index** (*which was disabled*) is rebuilt.

Now, let us come to the second part of the question which is in regards to the receiving of the error when a clustered index is ‘enabled’.

**Clustered indexes** can be disabled but cannot be enabled again; they have to be rebuilt to become *enabled*. It is indeed a common thinking that something which we have ‘disabled’ can be ‘enabled’ but the syntax for this is ‘rebuild’.

Let us go over this example where inserting the data is not possible when a **clustered index** is disabled.

USE AdventureWorks

GO

-- Create Table

CREATE TABLE [dbo].[TableName](

[ID] [int] NOT NULL,

[FirstCol] [varchar](50) NULL,

CONSTRAINT [PK\_TableName] PRIMARY KEY CLUSTERED

([ID] ASC)

)

GO

-- Create Nonclustered Index

CREATE UNIQUE NONCLUSTERED INDEX [IX\_NonClustered\_TableName] ON [dbo].[TableName]

([FirstCol] ASC)

GO

-- Populate Table

INSERT INTO [dbo].[TableName]

SELECT 1, 'First'

UNION ALL

SELECT 2, 'Second'

UNION ALL

SELECT 3, 'Third'

GO

-- Disable Nonclustered Index

ALTER INDEX [IX\_NonClustered\_TableName] ON [dbo].[TableName] DISABLE

GO

-- Insert Data should work fine

INSERT INTO [dbo].[TableName]

SELECT 4, 'Fourth'

UNION ALL

SELECT 5, 'Fifth'

GO

-- Disable Clustered Index

ALTER INDEX [PK\_TableName] ON [dbo].[TableName] DISABLE

GO

-- Insert Data will fail

INSERT INTO [dbo].[TableName]

SELECT 6, 'Sixth'

UNION ALL

SELECT 7, 'Seventh'

GO

/\*

Error: Msg 8655, Level 16, State 1, Line 1

The query processor is unable to produce a plan because the index 'PK\_TableName' on table or view 'TableName' is disabled.

\*/

-- Reorganizing Index will also throw an error

ALTER INDEX [PK\_TableName] ON [dbo].[TableName] REORGANIZE

GO

/\*

Error: Msg 1973, Level 16, State 1, Line 1

Cannot perform the specified operation on disabled index 'PK\_TableName' on table 'dbo.TableName'.

\*/

-- Rebuliding should work fine

ALTER INDEX [PK\_TableName] ON [dbo].[TableName] REBUILD

GO

-- Insert Data should work fine

INSERT INTO [dbo].[TableName]

SELECT 6, 'Sixth'

UNION ALL

SELECT 7, 'Seventh'

GO

-- Clean Up

DROP TABLE [dbo].[TableName]

GO

I hope this example is clear enough.